Подписка на новости

Опрос

Нужны ли комментарии к статьям? Комментировали бы вы?

Реклама

 

2011 №6

Создание точных SPICE-моделей для малошумящих микромощных прецизионных усилителей

Лафонтен Дон (LaFontain Don)


Перевод: Иоффе Дмитрий


В современных условиях конкуренции на динамично развивающихся рынках все больше и больше потребителей электронных компонентов запрашивают у производителей SPICE-модели для всестороннего моделирования схем. Разработчики систем требуют все более точных моделей для всех типов интегральных схем (ИС). Ранние SPICE-модели (1980 г.) содержали небольшое число нелинейных элементов, при этом время моделирования минимизировалось за счет точности.

Введение

Современные SPICE-модели, благодаря увеличению мощности компьютеров, позволяют увеличить количество нелинейных элементов и улучшить точность схем. В статье описан метод разработки многокаскадной модели малошумящего микромощного операционного усилителя. Разработка этой модели основана на статье [1]. В окончательную модель внесено несколько ключевых архитектурных изменений, которые требуются для современной модели малошумящего микромощного прецизионного усилителя.

В статье представлен систематизированный процесс, который упрощает понимание того, как надо создавать точную SPICE-модель. Это получается благодаря архитектуре модели, при которой входной сигнал проходит через восемь каскадов. Вы можете легко рассчитать параметры этих восьми каскадов на ручном калькуляторе или в Excel. В статье не обсуждается работа со SPICE, предполагается, что читатель знаком с этим программным обеспечением.

Модель, представленная в этой статье, соответствует ISL28127 — усилителю с однополюсной передаточной функцией и полосой пропускания 10 МГц. Для моделирования более скоростных усилителей со многими полюсами и нулями можно использовать AN-138 [1].

Модель содержит параметры по переменному току для шума вида 1/f и широкополосного шума, скорости нарастания, КОСС (коэффициент ослабления синфазного сигнала, common-mode rejection ratio, CMRR), усиления и фазового сдвига. Параметры модели по постоянному току включают VOS (входное напряжение смещения), IOS (входной ток), общий ток потребления и размах напряжения на выходе. В модели используются типовые параметры для температуры 25 °С, приведенные в спецификации [2].

Основой точной модели является входной каскад. Чем ближе ваша модель входного каскада к реальности, тем более точные результаты вы получите. Чтобы получить точное представление о работе усилителя по переменному току, достаточно небольшого числа параметров процессов, происходящих в транзисторах входного каскада.

Другое преимущество предлагаемой архитектуры — это возможность моделировать усилители с двухполярным питанием. Ни один из блоков обработки сигнала не требует опорного потенциала «земли». Вместо этого после преобразования дифференциального сигнала в несимметричный все внутренние напряжения отсчитываются от середины между напряжениями источников питания, подобно тому, как это происходит в реальном усилителе.

Мы обсудим следующие темы:

  • Различные каскады SPICE-модели: каскад шумового напряжения; входной каскад; первый каскад усиления; второй каскад усиления; каскад опорного напряжения середины питания; каскад изоляции питания; каскад синфазного усиления; выходной каскад.
  • Как работают каскады ИТУН.
  • Как работают выходные каскады ИТУН.
  • Систематизированный процесс расчета параметров модели.
  • Результаты моделирования и их сравнение с поведением реального устройства.

Последовательные каскады

На рис. 1 показана схема SPICE-модели, а в листинге приведен список ее цепей. Обратите внимание на то, что единственная схема, напоминающая усилитель, — это входной каскад. Все остальные каскады обрабатывают входной сигнал при помощи источников тока, управляемых напряжением (ИТУН), и источников напряжения, управляемых напряжением (ИНУН), наряду с диодами, источниками постоянных напряжений, простыми резисторами, конденсаторами и катушками индуктивности.

 Схема SPICE-модели

Рис. 1. Схема SPICE-модели
* source ISL28127_SPICEmodel
* Revision C, August 8th 2009 LaFontaine
* Model for Noise, supply currents, 150dB f=50Hz
CMRR, *128dB f=5Hz AOL
*Copyright 2009 by Intersil Corporation
*Refer to data sheet “LICENSE STATEMENT” Use of
*this model indicates your acceptance with the
*terms and provisions in the License Statement.
* Connections: +input
* | –input
* | | +Vsupply
* | | | –Vsupply
* | | | | output
* | | | | |
.subckt ISL28127subckt Vin+ Vin–V+ V– VOUT
* source ISL28127_SPICEMODEL_0_0
*
*Voltage Noise
E_En IN+ VIN+ 25 0 1
R_R17 25 0 377.4
D_D12 24 25 DN
V_V7 24 0 0.1
*
*Input Stage
I_IOS IN+ VIN– DC 1e–9
C_C6 IN+ VIN– 2E–12
R_R1 VCM VIN– 5e11
R_R2 IN+ VCM 5e11
Q_Q1 2 VIN– 1 SuperB
Q_Q2 3 8 1 SuperB
Q_Q3 V–– 1 7 Mirror
Q_Q4 4 6 2 Cascode
Q_Q5 5 6 3 Cascode
R_R3 4 V++ 4.45e3
R_R4 5 V++ 4.45e3
C_C4 VIN– 0 2.5e–12
C_C5 8 0 2.5e–12
D_D1 6 7 DX
I_IEE 1 V–– DC 200e–6
I_IEE1 V++ 6 DC 96e–6
V_VOS 9 IN+ 10e–6
E_EOS 8 9 VC VMID 1
*
*1st Gain Stage
G_G1 V++ 11 4 5 0.0487707
G_G2 V–– 11 4 5 0.0487707
R_R5 11 V++ 1
R_R6 V–– 11 1
D_D2 10 V++ DX
D_D3 V–– 12 DX
V_V1 10 11 1.86
V_V2 11 12 1.86
*
*2nd Gain Stage
G_G3 V++ VG 11 VMID 4.60767E–3
G_G4 V–– VG 11 VMID 4.60767E–3
R_R7 VG V++ 572.958E6
R_R8 V–– VG 572.958E6
C_C2 VG V++ 55.55e–12
C_C3 V–– VG 55.55e–12
D_D4 13 V++ DX
D_D5 V–– 14 DX
V_V3 13 VG 1.86
V_V4 VG 14 1.86
*
*Mid supply Ref
R_R9 VMID V++ 1
R_R10 V–– VMID 1
I_ISY V+ V– DC 2.2E–3
E_E2 V++ 0 V+ 0 1
E_E3 V–– 0 V– 0 1
*
*Common Mode Gain Stage with Zero
G_G5 V++ VC VCM VMID 31.6228e–9
G_G6 V–– VC VCM VMID 31.6228e–9
R_R11 VC 17 1
R_R12 18 VC 1
L_L1 17 V++ 3.183e–3
L_L2 18 V–– 3.183e–3
*
*Output Stage with Correction Current Sources
G_G7 VOUT V++ V++ VG 1.11e–2
G_G8 V–– VOUT VG V–– 1.11e–2
G_G9 22 V–– VOUT VG 1.11e–2
G_G10 23 V–– VG VOUT 1.11e–2
D_D6 VG 20 DX
D_D7 21 VG DX
D_D8 V++ 22 DX
D_D9 V++ 23 DX
D_D10 V–– 22 DY
D_D11 V–– 23 DY
V_V5 20 VOUT 1.12
V_V6 VOUT 21 1.12
R_R15 VOUT V++ 9E1
R_R16 V–– VOUT 9E1
*
.model SuperB npn
+ is=184E–15 bf=30e3 va=15 ik=70E–3 rb=50
+ re=0.065 rc=35 cje=1.5E–12 cjc=2E–12
+ kf=0 af=0
.model Cascode npn
+ is=502E–18 bf=150 va=300 ik=17E–3 rb=140
+ re=0.011 rc=900 cje=0.2E–12 cjc=0.16E–12f
+ kf=0 af=0
.model Mirror pnp
+ is=4E–15 bf=150 va=50 ik=138E–3 rb=185
+ re=0.101 rc=180 cje=1.34E–12 cjc=0.44E–12
+ kf=0 af=0
.model DN D(KF=6.69e–9 AF=1)
.MODEL DX D(IS=1E–12 Rs=0.1)
.MODEL DY D(IS=1E–15 BV=50 Rs=1)
.ends ISL28127subckt

Листинг. Список цепей SPICE-модели, представленной на рис. 1

Схема состоит из восьми различных функциональных блоков. Все блоки мы рассмотрим в следующих разделах, вместе с деталями их функционирования и особенностями разработки.

Каскад шумового напряжения

Первый каскад в схеме модели, считая слева направо, — это каскад шумового напряжения. Этот каскад генерирует шум вида 1/f и широкополосный шум. Чтобы генерировать широкополосное шумовое напряжение прецизионного усилителя, равное всего 4 нВ/√Гц, параметры kf (коэффициент фликкер-шума) и af (экспонента фликкер-шума) для всех диодов и транзисторов модели нужно сделать равными нулю. Чтобы уменьшить уровень шума модели до единиц нановольт, может понадобиться уменьшить шумы Джонсона в схеме, снижая, где только можно, величины сопротивлений. Перед тем как уменьшать значения сопротивлений, нужно рассчитать их стандартные значения и полностью отладить модель. Только после того как это сделано, можно перейти к настройке каскада шумового напряжения, уменьшая величины сопротивлений до 1 Ом, пока при изменении gm и постоянных времени сохраняется неизменная передаточная функция для данного каскада. Сопротивления резисторов R5, R6 и R9–R12 легко можно сделать равными 1 Ом. Для усилителей с уровнем широкополосного шума порядка сотен нановольт уменьшение шума Джонсона может оказаться необязательным. После первых проходов моделирования будет видно, насколько необходим этот шаг. Когда широкополосный шум модели станет меньше шума усилителя, пользователь может отрегулировать шум 1/f и широкополосный шум, изменяя DN, R17 и V5.

Входной каскад

Усилитель ISL28127 был выбран при написании этой статьи для того, чтобы проиллюстрировать уровень точности, которого можно достичь, если точно моделировать входную структуру усилителей. Входной каскад модели ISL28127 содержит пять биполярных транзисторов, которые моделируют реальную конфигурацию устройства, как показано на рис. 1. Однако так сделано не во всех SPICE-моделях. На рис. 2, 3 представлены типовые nMOS и pMOS входные каскады соответственно.

 Типовой nMOS входной каскад

Рис. 2. Типовой nMOS входной каскад


 Типовой pMOS входной каскад

Рис. 3. Типовой pMOS входной каскад

Входной каскад модели может состоять из тех же устройств (n-p-n-, p-n-p-, p- или n-канальные MOSFET или полевые транзисторы с p-n-переходом), что и в реальном усилителе. Кроме того, входной каскад содержит источник тока для моделирования тока смещения IOS, источник напряжения для моделирования напряжения смещения VOS, а также ИНУН с R1 и R2 для оценки КОСС устройства.

Первый каскад усиления

Назначение первого каскада усиления — обеспечить ситуацию, при которой произведение его усиления на усиление входного каскада было бы равно 1. Это упрощает расчеты для определения компонентов, ограничивающих скорость нарастания во втором каскаде. Диоды D2 и D3 вместе с источниками постоянного напряжения V1 и V2 могут быть необязательными, так как их функция состоит в ограничении размаха выходного напряжения, и это можно сделать в следующем каскаде. Мы оставили их, потому что это нам ничего не стоит. Постоянные напряжения V1 и V2 должны быть немного больше, чем V3 и V4 во втором каскаде усиления. В результате основное ограничение амплитуды сигнала происходит в первом каскаде, а окончательная подгонка — во втором.

Второй каскад усиления

Во втором каскаде усиление с разомкнутой обратной связью, полоса пропускания и скорость нарастания выходного напряжения усилителя регулируются с помощью G3, G4, R7, R8, C2 и C3. Диоды D4 и D5 вместе с источниками постоянных напряжений V3 и V4 используются для задания максимального размаха выходного напряжения.

Каскад опорного напряжения середины питания

Каскад опорного напряжения середины питания — это просто два одинаковых резистора R9 и R10. Эти резисторы используются для формирования опорного напряжения, находящегося посередине между напряжениями питания. Сопротивления этих резисторов установлены равными 1 Ом для уменьшения шума Джонсона в модели. Большой ток, который течет через эти резисторы, прозрачен для модели пользователя благодаря каскаду изоляции питания.

Каскад синфазного усиления

Каскад синфазного усиления содержит два ИТУН, которые работают на два одинаковых резистора, подключенных к шинам питания последовательно с индуктивностями. Эти индуктивности моделируют типовой спад КОСС, который в большинстве усилителей происходит при увеличении входной частоты. Источники тока управляются входным синфазным напряжением (создаваемым на резисторах R1 и R2 во входном каскаде) относительно середины между напряжениями питания. Каждый управляемый источник имеет gm, равное обратной величине соответствующего сопротивления, поделенной на КОСС усилителя для постоянного сигнала (формула 10). Индуктивности добавляют ноль к синфазному усилению, что эквивалентно добавлению полюса в КОСС. Синфазное напряжение после масштабирования и наложения частотной характеристики поступает на входной каскад через ИНУН, моделирующий напряжение смещения.

Каскад изоляции питания

Каскад изоляции питания состоит из двух ИНУН и источника тока. Этот каскад позволяет пользователю программировать общий ток потребления усилителя при помощи корректировки всего одного пункта в списке цепей. Он также отделяет внутренние потребляемые токи от внешнего тока потребления, видимого пользователю. Это позволяет корректно моделировать ток потребления для микромощных усилителей с низким шумовым напряжением.

Выходной каскад

Работа выходного каскада не вполне очевидна. Выходной сигнал усилителя после наложения частотной характеристики появляется как напряжение относительно середины питания, приложенное к входам G7 и G8. Последние нагружены на два одинаковых резистора, подключенных к шинам питания, и работают как активные генераторы тока. И G7, и G8 формируют достаточный ток, чтобы обеспечить желаемое падение напряжения на этих параллельных резисторах. (Подробнее об этом рассказано в разделе «Как работают ИТУН выходного каскада».)

Когда на выходе нет нагрузки, модель не потребляет ток от источников питания и ведет себя так, как и полагается выходу усилителя. Правильное моделирование выходного сопротивления означает, что усиление по постоянному току в усилителе с разомкнутой обратной связью будет адекватно уменьшаться по мере увеличения нагрузки усилителя.

Когда к выходу будет приложена нагрузка, по обеим шинам питания потекут одинаковые токи. Чтобы поведение модели походило на поведение реального усилителя, G9 и G10 отводят от источников питания соответствующий ток.

Защиту от короткого замыкания на выходе обеспечивают диоды D6 и D7 вместе с источниками постоянного напряжения V5 и V6. При коротком замыкании выходное напряжение привязывается к напряжению предыдущего каскада, формирующего частотную характеристику. Выходной ток короткого замыкания задается настройкой напряжений V5 и V6.

Как работают каскады ИТУН

Когда напряжение на входах G1 и G2 увеличивается (рис. 4), возрастает результирующее напряжение в средней точке. Аналогично, когда напряжение на входах уменьшается, напряжение в средней точке также уменьшается. Если gm каскада равно величине, обратной параллельному сопротивлению резисторов, то каскад имеет положительное единичное усиление.

 Работа ИТУН

Рис. 4. Работа ИТУН

Несимметричный эквивалент схемы на рис. 4 показан на рис. 5. Такая схема иногда нагляднее представляет прохождение сигнала по каскадам.

 Несимметричный эквивалент схемы на рис. 4

Рис. 5. Несимметричный эквивалент схемы на рис. 4

Как работают ИТУН выходного каскада

На рис. 6 объясняется, как работает выходной каскад при неизменном входном напряжении, при увеличении входного напряжения и при его уменьшении.

 Работа ИТУН выходных каскадов

Рис. 6. Работа ИТУН выходных каскадов

Методика расчета параметров модели

В таблице приведен список параметров усилителей, которые нужны для расчета параметров модели. Значения, показанные в таблице, относятся к модели усилителя ISL28127.

Таблица. Параметры устройства

Параметр Значение Комментарии
Ток потребления, А 2,2×10–3
VCC, В 15
VEE, В –15
IEE, В 200×10–6 Дифференциальный входной ток
Скорость нарастания, В/с 3,6×106
fp1, Гц 5 Главный полюс (рис. 7)
AVOL, В/В 2640×103 Усиление с разомкнутой ОС, 128,43 дБ
VOS, В 1×10–5
IOS, А 1×10–9
Температура, °С 25
Vt, В 0,0257
Дифференциальное входное сопротивление, Ом 5×10–11 Значение по умолчанию, если не задано
КОСС, В/В 3,16×107 150 дБ
FCM, Гц 50 Синфазный полюс
ROUT, Ом 45
ISC, мА 45
VOH, В 13,7 Максимальное выходное напряжение
VOL, В –13,7 Минимальное выходное напряжение

После того как определены величины для таблицы, по формулам (1–15) можно рассчитать параметры модели и внести их в схему SPICE.

С помощью приведенных далее формул можно определить параметры модели для схемы SPICE. Если ввести их в таблицу Excel, то можно будет изменять критические параметры и тут же наблюдать влияние изменений на работу усилителя. Расчеты приводятся для каждого каскада модели.

Входной каскад и расчет каскада усиления

Процесс задания скорости нарастания и полосы единичного усиления состоит из трех шагов:

  • Зная IEE и скорость нарастания, определить емкость конденсатора (1). Таким образом мы определим максимальную частоту для однополюсной RC-цепи и, следовательно, полосу единичного усиления.
  • Зная частоту основного полюса, определим величину сопротивления резистора (2). Тем самым мы найдем точку излома для RC-цепи.
  • Зная желаемое усиление с разомкнутой обратной связью и сопротивление RC-цепи, определим gm ИТУН.

Шаг 1

C2 = C3 = IEE/скорость нарастания = (200×10–6)/(3,6×10–6) = 55,55 пФ, (1)

где IEE — это величина тока входа дифференциальной пары (рис. 1). При нарастании сигнала весь этот ток мгновенно течет через одну сторону дифференциальной пары (до момента срабатывания обратной связи). Формула (1) используется для расчета емкости конденсатора, задающего скорость нарастания модели. Эта формула основана на выражении IC = C×dv/dt, где скорость нарастания равна dv/dt, а IEE равен IC.

По формуле 2, зная емкости C2 и C3 и частоту главного полюса fp1, можно рассчитать значения сопротивлений.

Шаг 2

R7 = R8 = 1/(2πfp1C2,3) = 1/(2π×5×55,55 пФ) = 572,958 МОм, (2)

где fp1 — главный полюс (рис. 7).

 Зависимость усиления с разомкнутой ОС от частоты

Рис. 7. Зависимость усиления с разомкнутой ОС от частоты

На рис. 7 показано соотношение между полосой единичного усиления, главным полюсом и усилением с разомкнутой обратной связью (AVOL).

Шаг 3

G3 = G4 = AVOL/R7,8 = (2640×106)/(572,958×106) = 4,6×10–3. (3)

Вспомним, что произведение коэффициента усиления первого каскада усиления на коэффициент усиления входного каскада должно быть равно единице. Напряжение, которое нужно подать на входы G3 и G4, чтобы через R7 и R8 протекал ток 200×10–6, рассчитывается по формуле:

gm = 1/V ⇒ VG3,4 = 1/gm = (200×10–6)/(4,6×10–3) = 4,3 мВ. (4)

Из-за ограниченной скорости нарастания ток через любой из резисторов R3 или R4 будет ограничен на уровне 200×10–6. Полярность входного напряжения определяет, через какой из резисторов течет ток: при положительной полярности — через R4, при отрицательной — через R3. Протекая через резистор с сопротивлением 4,45 кОм, этот ток вызывает падение напряжения (200×10–6)×4,45 кОм = 890 мВ. Это падение напряжения, в свою очередь, появляется на входах G1 и G2. Чтобы общее усиление входного каскада и первого каскада усиления было равно единице, нам нужно вычислить gm для G1 и G2 таким образом, чтобы их выходное напряжение было равно 43,4 мВ (4) при напряжении 890 мВ на их входах. Если мы сделаем сопротивления резисторов, параллельных выходам G1 и G2, равными 1 Ом, то напряжение будет равно току и мы сможем записать (5), чтобы получить gm для G1 и G2:

G1 = G2 ⇒ gm = 1/V = (43,4×103)/(890×10–3) = 48,77×10–3. (5)

Если документация на изделие недоступна, сделаем сопротивления R3 и R4 равными 1 Ом, чтобы рассчитать напряжение на входах G1 и G2:

R3 = R4 = 4,45 кОм (из документации). (6)

Формулы (7) и (8) используются для того, чтобы установить напряжения от V1 до V4 для получения максимального размаха напряжения на выходе. Выходное напряжение будет ограничиваться сверху на уровне, равном V++–(V1,3+VD2, D4) для положительного размаха входного напряжения и V––+(V2,4+VD3, D5) для отрицательного.

V1,3 = VCC–(VOUTMAX)+VTLn(2IEE/IS), (7)

V2,4 = (–VOUTMAX)–VEE+VTLn(2IEE/IS), (8)

где VT = 0,02585 В при Т = +25 °С, IS = 1×10–12 А (для обоих диодов).

Вы можете подставить некоторые параметры из спецификации непосредственно в модель. Это:

  • EOS — входное напряжение смещения (только составляющая по постоянному току);
  • IOS — входной ток смещения;
  • Cdiff — входная дифференциальная емкость (не показана в этой модели).

Каскад синфазного усиления

R11 = R12 = 1 МОм. (9)

G7 = G8 = 1/(R11,12×KOCC). (10)

L1 = L2 = R11,12/(2πfp(cm)), (11)

где fp(cm) — синфазный полюс на кривой зависимости КОСС от частоты (подобно частоте главного полюса, показанной на рис. 7).

Выходной каскад

Если установить gm равным обратному числу от 2ROUT, то ИТУН G7–G10 будут иметь единичное усиление. Величина 2ROUT зависит от следующего условия: необходимо, чтобы выходные токи вытекали из одной шины питания.

G7 = G8 = G9 = G10 = 1/2ROUT. (12)

R15 = R16 = 2ROUT. (13)

V3 = ISC×0,764×ROUT–VTLn(20×106/Is). (14)

V3 = |ISC×0,764×ROUT|–VTLn(20×106/Is). (15)

Результаты моделирования

На рис. 8–15 результаты моделирования сравниваются с поведением реального устройства. Чтобы провести полное сравнение, нужно взять данные из спецификации [2].

 Входное шумовое напряжение: а) согласно справочным данным; б) по результатам моделирования

Рис. 8. Входное шумовое напряжение:
а) согласно справочным данным; б) по результатам моделирования


 Зависимость усиления с замкнутой обратной связью от частоты: а) согласно справочным данным; б) по результатам моделирования

Рис. 9. Зависимость усиления с замкнутой обратной связью от частоты:
а) согласно справочным данным; б) по результатам моделирования


Зависимость усиления с замкнутой обратной связью от частоты при разных отношениях Rf/Rg: а) согласно справочным данным; б) по результатам моделирования

Рис. 10. Зависимость усиления с замкнутой обратной связью от частоты при разных отношениях Rf/Rg:
а) согласно справочным данным; б) по результатам моделирования


Зависимость усиления с замкнутой обратной связью от сопротивления нагрузки RL: а) согласно справочным данным; б) по результатам моделирования

Рис. 11. Зависимость усиления с замкнутой обратной связью от сопротивления нагрузки RL:
а) согласно справочным данным; б) по результатам моделирования


Зависимость усиления с замкнутой обратной связью от емкости нагрузки CL: а) согласно справочным данным; б) по результатам моделирования

Рис. 12. Зависимость усиления с замкнутой обратной связью от емкости нагрузки CL:
а) согласно справочным данным; б) по результатам моделирования


Отклик на большой перепад сигнала (10 В): а) согласно справочным данным; б) по результатам моделирования

Рис. 13. Отклик на большой перепад сигнала (10 В):
а) согласно справочным данным; б) по результатам моделирования


Зависимость усиления с разомкнутой обратной связью и сдвига по фазе от частоты: а) согласно справочным данным; б) по результатам моделирования

Рис. 14. Зависимость усиления с разомкнутой обратной связью и сдвига по фазе от частоты:
а) согласно справочным данным; б) по результатам моделирования


Зависимость КОСС от частоты: а) согласно справочным данным; б) по результатам моделирования

Рис. 15. Зависимость КОСС от частоты:
а) согласно справочным данным; б) по результатам моделирования

Заключение

В статье представлен расчет точной SPICE-модели для современных малошумящих и микромощных прецизионных усилителей. Исключительная точность моделирования, проверенная при сравнении с параметрами реального усилителя, достигнута благодаря увеличившейся мощности современного компьютера и точному моделированию входного каскада на пяти биполярных транзисторах; для каждого типа такого транзистора параметры задавались индивидуально. По сравнению с предыдущими предлагаемая модель дает возможность моделировать шумы порядка единиц нановольт и очень небольшие токи потребления, характерные для микромощных усилителей.

Автор благодарит Оскара Мансиллу (Oscar Mansilla) за большую помощь в работе с программным обеспечением SPICE, особенно в генерации подсхем из списка цепей и разработке пользовательской библиотеки SPICE. А также благодарит Боба Поспишила (Bob Pospisil) за консультации по операционным усилителям и помощь при разрешении различных проблем.

Литература

  1. Alexander M., Bowers D. F. SPICE-Compatible Op Amp Macro-Models. Analog Devices. Application Note AN-138.
  2. ISL28127, ISL28227 FN6633 Intersil data sheet — http://www.intersil.com/data/fn/fn6633.pdf
  3. Bowers D. F. Minimizing Noise in Analog Bipolar Circuit Design. Precision Monolithics, Inc. // IEEE 1989.

Скачать статью в формате PDF  Скачать статью Компоненты и технологии PDF

 


Другие статьи по данной теме:

Сообщить об ошибке